;redcode-94f
;name Phluph and Stuff v03
;author inversed
;strategy LP paper with PSpace-tweaked boot distance
;strategy (CSEC 2005 2nd chance tournament final entry against Nenad Tomasev)
;assert 1
;This is my warrior from f hill. At the time of writing this comment, I _t0t4lly_ pwn the f hill:
;HAS_b13 is N1 with 70(!!!) points gap to closest warrior made not by me. However, I'll not submit it
;because it slightly losses to Nenad's NTf5. I don't want to reveal Phluph 3 that fast, but I have to. 
;It's an LP paper with BioMech's (my LP paper) surplus length trick (it's evident but it works very good;
;I haven't seen it in any other paper yet): length in copying code is larger than actual paper length.
;It allows to have some extra dat bombing without any special code for this and it also allows not to use
;ADD instruction and have a decent spreading of papers. Second thing is very important in this round:
;my paper has only 5 instructions and complete boot takes only 14 cycles, so practically noone can kill 
;it before it's booted. Actually, right now noone can kill it at all ;) Just look at the hill: 0.6%
;of losses (0.1% if we exclude Fizmo's Viper to which it losses (oh no ;) 5.3%) and it beats *everything*.  
;But it's partly due to PSpace. I'm switching boot distance with simple switch-on-loss-or-tie switcher.
;Every time it's not winning, it increments a counter and next time this counter is multiplied with
;nice MOD-1 constant to get boot distance, so it coveres approx. every fourth cell in random pattern.
;Nenad is a very strong PRO player, but this time he is doomed (unless some kind of miracle happens).
;Why I don't want to reveal Phluph now? Look at quarterfinal results: 30% of participants sent HullaClones. 
;Revealing good things too fast slows down the progress a lot. Release of Quake 1 engine slowed down 
;devlopment of 3d engines for many years (up to present moment): most developers just bought it 
;and used without changes. Ok, enough chatting, I'm risking to miss the deadline.

l	equ	23
zofs	equ	1656	;1650
dec	equ	-700

bd1	equ	1400
pad	equ	150

p_str	equ	222
fac	equ	1381
safe	equ	3600

org	res

i	for	pad
	dat	i*3039,	i*3359
	rof

res	ldp	#0,	0       ;load result
str	ldp	#p_str,	0       ;load current strategy
	seq	#1,	res     ;if not win then...
	nop	0,	>str    ;inc strat
	stp.b	str,	#p_str  ;save current
	mul	#fac,	str
	mod	#safe,	str
	add.ba	str,	bp

boot	mov	<bp,	{bp
	for	4
	mov	<bp,	{bp
	rof
bp	jmp	-1795,	to+1

from	mov	#l,	#0
loop	mov	<from,	{to
	jmn	loop,	from
	spl	from,	{dec
to	jmz	zofs,	*0

i	for	MAXLENGTH-CURLINE
	dat	i*3039,	i*3359
	rof