;redcode-94nop
;name The Catcher in the Rye
;author Roy van Rijn
;assert 1
;
;
;
; First I created a benchmark (and deleted it, see logs 26-10-05)
;   then I tried all warriors I could find
;   seems that mostly oneshots and Hullabaloo do well
;
; So I optimized Myrmidon (my best oneshot) and Hullabaloo
;   they scored almost the same against my benchmark..
;   after a one-on-one fight the best warrior was the Hullabaloo-clone
;
; I suspect others will do the same (benchmarking)
;   they will also notice oneshots are best and submit that
;   and then having Hulla might be a slight advantage
;
;Sending: Hullabaloo in 3800
;
;Some more testing, but WAIT! Hullabaloo is only strong against a few oneshots
;   not all oneshots in my benchmark... that is VERY dangerous in this round
;
;Back to the drawing board.. time to think of another strategy
;   looking at my enemies, fiveop might make a oneshot, so does LAchi
;   he started out making bombing-oneshots and later some papers.
;   inversed could make a oneshot, and simon is always tricky
;
;How about a oneshot that beats most other oneshots
;   I took my best oneshot up to date, Myrmidon
;   Optimized it a little bit against oneshots in 3800 core
;   And here is the replacement..just to tricky to send a stone/paper!
;
;Sending: Myrmidon clone for 3800
;
;(Never change strategies, stick with the first thing that comes to mind...)
;
;So much doubt...
;I'm going to test what was a better choice when this tournament is over!
;
;Being the favourite isn't fun at all... I can't win, only fail


ptr     dat     0               , sScan-8

for 3
        dat     0               , 0
rof

sw      dat     1,      13
g2      spl     #4110,  13
        dat     0,      0
        dat     0,      0
clr     spl     #sStep, sStep
        mov     *sw,    >ptr
        mov     *sw,    >ptr
        djn.f   -2,     }g2

for     14
        dat     0,      0
rof

sOff    equ     1060
sStep   equ     6801
sDiff   equ     83

pGo     add.f   clr,    sScan
        mov     sBomb,  *1
sScan   sne     *sOff,  >(sOff+sDiff)-7
        djn.f   pGo,    @-1
        add.f   sScan,  @clr+1
        djn.f   clr,    <533

for     5
        dat     0,      0
rof

sBomb   mov.i   {sDiff,  1
end pGo+2