;redcode-CSEC2005 
;name Mountain Troll 
;author Chip Wendell 
;strategy stone/imp 
;based on Fizmo's Elven King
;assert CORESIZE==3800 


;-------imp constants------------------------ 
iStep   equ     1267 


;-------stone constants---------------------- 
sStep    equ    1030 
sHop     equ    46 
sGate    equ    (sIncr-2) 
sHit     equ    (sLoop-sStep-sHop) 


;-------boot constants----------------------- 
ioff    equ     (iBoot   + 938) 
soff    equ     (iBoot   + 1333) 
iSep    equ     (iBoot   + 3280) 

for 7
	nop	1,2	;decoy
rof

iBoot   mov.i   iImp,           ioff 
        spl     1,              }892 
qtab2   spl     1,              }1341 
        spl     2,              }1715 
        mov.i   {iBoot,         <iBoot 
        mov.i   <sboot,         {saway 
saway   djn     soff,           #8 
sboot   jmp     @iBoot,         sBomb+1 

        for     4 
        dat     0,              0 
        rof 

sIncr   spl     #sStep,         <-sStep 
        mov.i   {sStep,         <sHit 
        mov.i   sBomb,          @-1 
        add.f   sIncr,          -2 
sLoop   djn.f   @-1,            <-sStep+sIncr 
        mov.i   sBomb,          >sGate 
        djn.f   -1,             >sGate 
sBomb   dat     <1267,          sHop+1 

        for     6 
        dat     0,              0 
        rof 

iGo     spl     #iSep,          #iImp+1 
        sub.f   #-iStep-1,      iLoop 
        mov.i   iImp,           }iGo 
iLoop   jmp     iSep-2*(iStep+1), >iImp+2*iStep-1 
iImp    mov.i   #iStep,         iStep 

end iBoot