;redcode
;assert 1
;n-ame Recon 2
;name Ratatosk
;a-uthor David Moore
;author Michal Janeczek
;strategy SNE scanner / SPL wiper
;strategy CWSET 2005 - Qualification round

; Look at pairs of cells that are 5 apart.
; When something is found, wipe it with 14 SPLs like this:
; ...X....X.....

; distance between scanned pairs:
step equ 2693   ; overcomes 3, 7, and 17 point imps

; 2693 * 119 = 1267   (1267 *  3 = 1)
; 2693 *  51 =  543   ( 543 *  7 = 1)
; 2693 *  21 = 3353   (3353 * 17 = 1)

ptr equ (scan-8)

        dat      19,  19
diff    spl  #-step, #-step
wipe    mov    diff, >ptr     ; hit 'em with SPLs
w2      mov   *wipe, >ptr     ; later, this becomes a DAT clear
        djn.a  wipe,  length

loop    sub    diff, @s2
scan    sne step - 2, step - 7   ; check a pair
        sub    diff,  scan
s2      seq   *scan, @scan    ; check another pair
        slt.a   #20,  scan    ; ignore self
timer   djn    loop, #2280    ; count down to DAT phase
length  sub.ba #0,  #-7      ; set up for SPL wipe
tweak   mov.ab @s2, @wipe
t2      jmn    *w2,  timer   ; when timer expires,
        djn.a  <tweak, {t2   ; go to DAT clear mode

for MAXLENGTH-CURLINE-6
        dat 0,0
rof

d equ (diff+3499)

decoy   nop >d, }d+1
        mov {d+2, {d+7
        mov {d+3, {d+9
        djn.a scan, <d+5

end decoy