;redcode-94
;name Planter
;author datagram
;assert 1
;strategy "An experiment," said Planter.

        PIN 13

        org pThink

        ;; Scanner Constants

        ssep    EQU     2516
        sstep   EQU     3694
        djn1    EQU     4408

        ;; Clear Constants

        cNew    EQU     1
        cOff    EQU     401

        ;; Boot Constants

        bSep    EQU     55
        bOff    EQU     671

        ;; P-Switching Constants

        pRes    EQU     #0
        pCell   EQU     #3987

        ;; Bootstrap
        ;  8 lines

sBoot   mov     (sGo-3)+8,      (sGo-3)+bOff
cBoot   mov     gate+8,         gate+bOff+bSep-2
        mov     {sBoot,         <sBoot
        mov     {sBoot,         <sBoot
        mov     {cBoot,         <cBoot
        mov     {cBoot,         <cBoot
        djn     -4,             #4
        jmp     sScan+bOff-8,   0

        dat     0,              0
        dat     0,              0

        ;; Scanner
        ;  SNE scanner with zooom trick
        ;  9 lines

        nop     #sstep,         sstep
        mov     }4,             >1322
sClear  mov     cGo+bSep,       >-1
sGo     add.f   -3,             sScan
sScan   sne     }ssep+11,       ssep
        djn.f   sGo,            <djn1
        mov.b   sScan,          @sClear
        djn     {-2,            #10
        jmp     cGo+bSep-2,     0

        ;; Core clear
        ;  SJD Anti-Imp coreclear
        ;  9 lines

gate    dat     4009+cOff,      {12+cOff
jump    jmp     4009,           12
        dat     0,              0
        dat     0,              0
cptr    jmp     7829,           <2667
cGo     spl     #4007,          12
        mov     @2,             >gate
        mov     jump,           }gate
        djn.f   cGo+1,          {cGo

        ;; P-Brain
        ;  Determines strategy
        ;  9 lines

pThink  ldp.ab  pRes,           #0
str     ldp.a   pCell,          pStr
        sne.ab  #0,             pThink
lost    nop     >-2000,         }pStr
        mod.a   #3,             pStr
win     stp.ab  pStr,           pCell
pStr    jmp     @0,             sBoot
        dat     0,              sBoot
        dat     0,              pBoot

        dat     0,              0
        dat     0,              0


        ;; Paper
        ;  Kline sytle paper
        ;  11 lines

pBoot   spl     1,              {1000
        spl     1,              {2000
        spl     1,              {3000
pls     mov     plb,            >8
plc     mov     <pls,           <pln
pln     spl     @pln,           >-1356
        mov     plb,            <pln
        mov     plb,            <-1000
        mov     plb,            >200
        jmn.f   @0,             >pls
plb     dat     <2667,          <5334