;recode
;name dark return of test
;author el kauka

;comments: 
;thats a tough one. two rounds with diffrent max processes...
;i'm sure most of the people (or atleast brx) are as lazy as i am
;and send in a warrior thats works under both conditions. i've yet
;no clue about those lp papers, and they may not even work in the
;second round. so what's left? you're right: stones and scanners.
;i think sending in a scanners is quite a risk this time. i truely
;won't miss a good defence, but it's hard to do a scanner/imp
;so send a stone/imp. to gain a greater defence launch both - a and
; b imps. the stone should do the rest than...remember we only need
;one lucky hit at the enemy and can tie all the other rounds and still
;stay the winner of the match, 'cause we're only fighting one enemy and
;not a whole hill this time.



;hand written constants
;no time to optimize. just watched the pattern
;looking nice on the display...

istep	equ	2731 
dfirst	equ	-100
dstep	equ	3567
dstream	equ	-1000
away	equ	4014
saway	equ	2222
i1	equ	202
i2	equ	702
step	equ	2222
hop	equ	46
grap	equ	100
drop	equ	400
stream	equ	-1001
gap	equ	22


;boot code
	mov.i	imp,	imp+i1+away
	mov.i	imp2,	imp2+i2+away
	spl	1
for 4
	mov.i	<boot,	{boot
	mov.i	<sboot,	{sboot
rof
	
sboot	spl	bomb+2+saway,	bomb+2

;delay the imps until there are atleast 50 processes
;on the stone. seems i have no defence in the low
;process round - let's hope the stone does well
;enough...
	djn.b	0,	#38
	spl 1
	spl 1
boot	jmp	c1+4+away,	c1+4	

for gap
	dat	0,0
rof


;0.6c stone - no endgame
;it's nearly braindamaging to write
;a stone/dclear with only mod2 steps possible. but wait, let's
;stick to the plan: hit the enmemy luckly, tie the rest.
;a .6c stone seems to fit perfectly for this combat-role.

inc	spl	#step,	#step
ptr	mov.i	grap,	>drop
	mov.i	bomb,	@ptr
	mov.i	bomb,	*ptr
	add.f	inc,	ptr
	djn.f	ptr,	<stream
bomb	dat	<-1,	}hop


for gap
	dat	0,0
rof

;imp launcher
;there are other imp launchers out there
;launching a AND b imps.
;but i've found no one being as small as this one
istart  spl	#0,		<dstream
        add.x	imp+i1,		c1 
	add.a	imp2+i2,	c2	
c2	spl	i2+imp2-(istep*4), <istart
c1      djn.f	i1+imp-(istep*12),<-dfirst

for gap
	dat	0,	0
rof

imp	mov.i	#dstep, istep
imp2	mov.i	#istep,*0	


end