;redcode-94t
;name entryInVain
;author Nenad Tomasev
;assert CORESIZE==8192
;strategy stone/imp


istep equ 2731

zero equ qbomb
qtab3 equ qbomb

hStep equ    (-3439)
hTime equ    3100
hDjn  equ    2813
hOff  equ    5
hDist equ    2868

 org qgo
qbomb   dat >qoff, >qc2
pGo  mov hBomb, hBoot+hDist+hOff
 spl 2, }qb1    
qtab2 spl 2, }qb2     
 spl 1, }qb3     
 mov {pGo, {hBoot
hBoot spl hDist, {5282
 djn.f ilaunch, {5222
 for 9
 dat 0, 0
 rof
        dat zero-1, qa1
qtab1   dat zero-1, qa2
boot mov imp, imp+ibd
 djn.f pGo, {5333
 for 3
 dat 0, 0
 rof
 spl #0, 0
hLoop mov hBomb+hOff, @hPtr
hHit add #hStep*2, hPtr
hPtr mov hBomb+hOff, }hHit-hStep*hTime
 djn.f hLoop, <hDjn
hBomb dat hStep, >1
 for 9
 dat 0, 0
 rof
ibd equ 482
table equ (imp+1)
ilaunch mov.i (qtab2+1), #0
 jmp @table, }0
imp mov.i #istep, *0
rr for 9
 dat <1, (imp+ibd+(rr-1)*istep)
 rof
 for 14
 dat 0, 0
 rof


qc2 equ ((1+(qtab3-qptr)*qy)%CORESIZE)
qb1 equ ((1+(qtab2-1-qptr)*qy)%CORESIZE)
qb2 equ ((1+(qtab2-qptr)*qy)%CORESIZE)
qb3 equ ((1+(qtab2+1-qptr)*qy)%CORESIZE)
qa1 equ ((1+(qtab1-1-qptr)*qy)%CORESIZE)
qa2 equ ((1+(qtab1-qptr)*qy)%CORESIZE)
qz equ 2108
qy equ 243         ;qy*(qz-1)=1


;q0 mutation
qgo     sne qptr+qz*qc2, qptr+qz*qc2+qb2
        seq <qtab3, qptr+qz*(qc2-1)+qb2
        jmp q0, }q0
        sne qptr+qz*qa2, qptr+qz*qa2+qb2
        seq <qtab1, qptr+qz*(qa2-1)+qb2
        jmp q0, {q0
        sne qptr+qz*qa1, qptr+qz*qa1+qb2
        seq <(qtab1-1), qptr+qz*(qa1-1)+qb2
        djn.a q0, {q0
                                        ;q1 mutation
        sne qptr+qz*qb3, qptr+qz*qb3+qb3
        seq <(qtab2+1), qptr+qz*(qb3-1)+(qb3-1)
        jmp q0, }q1
        sne qptr+qz*qb1, qptr+qz*qb1+qb1
        seq <(qtab2-1), qptr+qz*(qb1-1)+(qb1-1)
        jmp q0, {q1

        sne qptr+qz*qb2, qptr+qz*qb2+qb2
        seq <qtab2, qptr+qz*(qb2-1)+(qb2-1)
        jmp q0
                                        ;qz mutation
        seq >qptr, qptr+qz+(qb2-1)
        jmp q2, <qptr
                                        ;q0 mutation
        seq qptr+(qz+1)*(qc2-1), qptr+(qz+1)*(qc2-1)+(qb2-1)
        jmp q0, }q0
        seq qptr+(qz+1)*(qa2-1), qptr+(qz+1)*(qa2-1)+(qb2-1)
        jmp q0, {q0
        seq qptr+(qz+1)*(qa1-1), qptr+(qz+1)*(qa1-1)+(qb2-1)
        djn.a q0, {q0
        jmz.f boot, qptr+(qz+1)*(qb2-1)+(qb2-1)

qoff equ -86
qstep equ -7
qtime equ 19

q0      mul.b *2, qptr
q2      sne {qtab1, @qptr
q1      add.b qtab2, qptr
        mov qtab3, @qptr
qptr    mov qbomb, }qz
        sub #qstep, qptr
        djn -3, #qtime
        djn.f boot, #0
 end