;redcode-94
;name Human
;author datagram
;strategy You see, Speaker? I would die to climb the fence that keeps us from the stars. 
;assert 1

        org     qgo

;imp constants:
        istep   equ     2731
        itime equ       501
        idjn1   equ     -10
        idjn2   equ     3400
        ioff    equ     1271+398-1271

;;stone constants
        sstep   equ     879

;;qscan misc
        qtab3   equ     qbomb


qbomb   dat     >qoff,          >qc2
        dat     0,                      0
        dat     0,                      <qb1
qtab2   dat     0,                      <qb2
        dat     0,                      <qb3
for 4
        dat     0,                      0
rof
iboot   spl     #ipump+ioff,    <-idjn1
        sub.f   #-(istep+1),    ijump
ipump   mov     imp,                    }-2
ijump   djn.f   ioff-2*(istep+1),       {-idjn2
imp     mov.i   #0,                     istep
for 3
        dat     0,                      0
rof
        dat     qtab3-1,        qa1
qtab1   dat     qtab3-1,        qa2
for 6
        dat     0,                      0
rof
        dat     sbomb,          sbomb+2903
start spl       2,                      <-636
        spl     2,                      <-345
        spl     1,                      <-190
        mov     }start-1,               >-4
        djn     sbomb+2903+1,   #5
        spl     iboot,          <-3845
        jmp     cboot,          <-929
for 6
        dat 0, 0
rof

cptr    nop     4,                      5
cgo     mov     *cptr,          >cptr
        mov     *cptr,          >cptr
        djn.f -2,                       >cptr
        dat     {-2731,         <3277
for 6
        dat     0,                      0
rof

sbomb dat        {2731,                 <3511
sstrt   spl      #0,                    #sstep
        mov      sbomb,                 >-1
        add.ab #sstep,          -2
send    djn      -2,                    <-3

for 3
        dat 0, 0
rof

cboot   mov     }cbptr,         >6
        mov     }cbptr,         >5
        mov     }cbptr,         >4
        mov     }cbptr,         >3
        mov     }cbptr,                 >2
        djn.f   qbomb-133+1,    <1500

cbptr   dat     cptr,                   qbomb-133

qc2     equ ((1+(qtab3-qptr)*qy)%CORESIZE)
qb1     equ ((1+(qtab2-1-qptr)*qy)%CORESIZE)
qb2     equ ((1+(qtab2-qptr)*qy)%CORESIZE)
qb3     equ ((1+(qtab2+1-qptr)*qy)%CORESIZE)
qa1     equ ((1+(qtab1-1-qptr)*qy)%CORESIZE)
qa2     equ ((1+(qtab1-qptr)*qy)%CORESIZE)
qz      equ 7694
qy      equ 197         ;qy*(qz-1)=1

qgo     sne     qptr+qz*qc2     , qptr+qz*qc2+qb2               ;q0
        seq     <qtab3          , qptr+qz*(qc2-1)+qb2
        jmp     q0              , }q0
        sne     qptr+qz*qa2     , qptr+qz*qa2+qb2
        seq     <qtab1          , qptr+qz*(qa2-1)+qb2
        jmp     q0              , {q0
        sne     qptr+qz*qa1     , qptr+qz*qa1+qb2
        seq     <(qtab1-1)      , qptr+qz*(qa1-1)+qb2
        djn.a   q0              , {q0
        sne     qptr+qz*qb3     , qptr+qz*qb3+qb3               ;q1
        seq     <(qtab2+1)      , qptr+qz*(qb3-1)+(qb3-1)
        jmp     q0              , }q1
        sne     qptr+qz*qb1     , qptr+qz*qb1+qb1
        seq     <(qtab2-1)      , qptr+qz*(qb1-1)+(qb1-1)
        jmp     q0              , {q1
        sne     qptr+qz*qb2     , qptr+qz*qb2+qb2
        seq     <qtab2          , qptr+qz*(qb2-1)+(qb2-1)
        jmp     q0                , <378                                ;qz
        seq     >qptr           , qptr+qz+(qb2-1)
        jmp     q2              , <qptr
        seq     qptr+(qz+1)*(qc2-1),qptr+(qz+1)*(qc2-1)+(qb2-1)
        jmp     q0              , }q0
        seq     qptr+(qz+1)*(qa2-1),qptr+(qz+1)*(qa2-1)+(qb2-1)
        jmp     q0              , {q0
        seq     qptr+(qz+1)*(qa1-1),qptr+(qz+1)*(qa1-1)+(qb2-1)
        djn.a   q0              , {q0
        jmz.f   start             , qptr+(qz+1)*(qb2-1)+(qb2-1)

qoff    equ     -86
qstep   equ     -7
qtime   equ     19

q0      mul.b   *2              , qptr
q2      sne     {qtab1          , @qptr
q1      add.b   qtab2           , qptr
        mov     qtab3           , @qptr
qptr    mov     qbomb           , }qz
        sub     #qstep          , qptr
        djn     -3              , #qtime
        djn.f   start             , #0