;redcode-cwset_rounds2
;author Sascha Zapf
;name Modus operandi
;strategy Stone/Imp hardly anti-scanner optimized
;assert 1

;------------ Comment ---------------
;Hi,
;
;puuuhhh at qualification i get the right strategy. Three 
;scissor are enough fodder for my Paper/Stone. But now, Chip is waiting...
;
;After his nice work on corewin and his awesome 4 in a 
;row success at Redcoders Frenzy Tournament he has my respect. I see two 
;points of matter.
;
;1) What strategy can score good under 8000 processes and under 
;20-50 processes without use of MAXPROCESSES or any other detection 
;of MAXPROCESSES. Try to detect if 50 Procs or more needs to spl 64 
;proceeses and look if that works, and if not use LP-strategy...
;
;2) What would Chip use ?
;
;For 1) 
;
;O.K, with 40 Processes you can design a nice and fast coreclear-paper 
;with a lower need of procs per instance. But here, we don't know if 
;it's 20 or 30 or 49. So common paper are not a good choice.
;
;Scanner, usually working with 1 process, so there is no difference 
;for them. After a direct hit at the spl a clear running with 50 procs 
;is much faster down as one runnign with 8000, but when working both doing 
;their job.
;
;Stones - While bombing stones with 20-50 procs are as much as powerfull 
;then the 8000er one and as much as weak like the clear...
;
;So, scanner or stone seems the strategy of my choice.
;
;For 2)
;
;It seems that Chip preferences Recon2 as a scanner. In 3 of the 4 rounds 
;he won he did it with a Recon2-clone.
;
;And i hope for that and my entry will be a Anti-Scanner-Optimized Stone/Imp 
;with Qscan as nice decoy.
;
;Hope for the best - and may be the core with me...
;
;-------------------------------------

zero    equ     qbomb
qtab3   equ     qbomb
qz      equ     5071;2108
qy      equ     3977;243

qc2 equ ((1 + (qtab3-qptr)*qy) % CORESIZE)
qb1 equ ((1 + (qtab2-1-qptr)*qy) % CORESIZE)
qb2 equ ((1 + (qtab2-qptr)*qy) % CORESIZE)
qb3 equ ((1 + (qtab2+1-qptr)*qy) % CORESIZE)
qa1 equ ((1 + (qtab1-1-qptr)*qy) % CORESIZE)
qa2 equ ((1 + (qtab1-qptr)*qy) % CORESIZE)

qoff    equ    -88
qstep   equ    -6;-7
qtime   equ    -16;-20

;-------Constants for optimization----------


;-------------------------------------------

        dat     0,              0
qbomb   dat     >qoff,          >qc2

;------ 45 instructions --------------------

     sBoot equ (uPtr+2314)   ;1890;2953)  ; 7867;2093
     iBoot equ (sBoot+uStp)

    decoy equ 4728

pGo: spl   2, <decoy+1
     spl   1, <decoy+2
     spl   1, <decoy+3
     mov   <uBmb,       {iPos      ; launch imp
     mov   {sPtr,       {sPos      ; launch stone
sPos:djn   sBoot+6,     #6         ; 5 processes for the stone
iPos:djn.f   iBoot+6, <decoy                 ; and 1 process for the imp

     uStp equ 7571;6979;587;703
     uTim equ 1101;681;1183

     spl   #0,       #0
uLp: mov   uBmb,     @uPtr
uHit:sub.x #uStp*2,  @uLp
uPtr:mov   {3470,    }uHit+2*uStp*uTim     ;2194  ; 1363 ;3582
     djn.f @uHit,    }uPtr
uBmb:dat   <uStp,    >1+6

     iStep equ 3277                ; 5-point imps

iPmp:spl   #iImp,       >-20
     sub.f #-iStep-1,   iJmp
     mov   iImp,        }iPmp
iJmp:jmp   iImp-2*(iStep+1),>iImp+2*iStep-1
iImp:mov.i #iStep/2,    iStep
    dat 0,0
sPtr: dat     -6               , 0 

for 25
dat 0,0
rof

;-------------------------------------------

        dat     0,              <qb1
qtab2   dat     0,              <qb2
        dat     0,              <qb3
        dat     0,              0
        dat     0,              0
        dat     0,              0
        dat     0,              0
        dat     zero-1,         qa1
qtab1   dat     zero-1,         qa2
        dat     0,              0
        dat     0,              0
        dat     0,              0
        dat     0,              0
        dat     0,              0

qgo sne qptr+qz*qc2, qptr+qz*qc2+qb2
    seq <qtab3,      qptr+qz*(qc2-1)+qb2
    jmp q0,          }q0
    sne qptr+qz*qa2, qptr + qz*qa2 + qb2
    seq <qtab1,      qptr+qz*(qa2-1)+qb2
    jmp q0,          {q0
    sne qptr+qz*qa1, qptr+qz*qa1+qb2
    seq <(qtab1-1),  qptr+qz*(qa1-1)+qb2
    djn.a q0,        {q0
    sne qptr+qz*qb3, qptr+qz*qb3+qb3
    seq <(qtab2+1),  qptr+qz*(qb3-1)+(qb3-1)
    jmp q0,          }q1
    sne qptr+qz*qb1, qptr+qz*qb1+qb1
    seq <(qtab2-1),  qptr+qz*(qb1-1)+(qb1-1)
    jmp q0,          {q1
    sne qptr+qz*qb2, qptr+qz*qb2+qb2
    seq <qtab2,      qptr+qz*(qb2-1)+(qb2-1)
    jmp q0,          }4443              ;extra attack
    seq >qptr,       qptr+qz+(qb2-1)
    jmp q2,          <qptr
seq qptr+(qz+1)*(qc2-1),qptr+(qz+1)*(qc2-1)+(qb2-1)
    jmp q0,          }q0
seq qptr+(qz+1)*(qa2-1),qptr+(qz+1)*(qa2-1)+(qb2-1)
    jmp q0,          {q0
seq qptr+(qz+1)*(qa1-1),qptr+(qz+1)*(qa1-1)+(qb2-1)
    djn.a q0,        {q0
    jmz.f pGo,       qptr+(qz+1)*(qb2-1)+(qb2-1)

q0      mul.b   *2,             qptr
q2      sne     {qtab1,         @qptr
q1      add.b   qtab2,          qptr
        mov     qtab3,          @qptr
qptr    mov     qbomb,          }qz
        sub     #qstep,         qptr
        djn     -3,             #qtime
        jmp     pGo,            }3256   ;extra attack
        dat     0,              0
        dat     0,              0
        dat     0,              0
        dat     0,              0

end qgo