;redcode-CSEC
;name Straight through the core
;author G.Labarga
;assert CORESIZE==8192
;strategy *** CSEC2005 Round 2 ***
;strategy bomber + sd-clear
;
;Round 2 comments:
;-----------------
; There are not many warriors that work well under both normal and lp
;settings but canners and oneshots. It might be hard to make a paper for this round.
; I don't know much about Simon's warriors, but i know he has some
;nice oneshots, so i decided to create an agressive warrior against oneshots
;and scanners, having some anti-imp cappability too, so i can
;some some points if he submits a paper.
;
;The strat is basically a stone/clear
;
;The stone bombs with empty core and also with an anti-clear bomb
;I don't know if i should call it bomber or stone.
; It is quite fast and disruptive, and self hits to become
;a slow core clear. It seems to be very effective.
;
; The clear only makes one SPL pass and not even complete,
;for not to hit the bomber with SPL's and slow-down the warrior.
;It kills the bomber with dats and remains as an anti-imp tool. 
;The clear just has to stun imp spirals, stones and other clears,
;and does its duty well.
;
;Obviously this warrior has nearly no chance against papers
; and certain weird lp variations like Roy's Daub fussion.
; I finaly attemped to add a Qscan, but had no time to 
;fit one and make it work on a 8192 core.
; I hope not no see something paper-ish from Simon.

;--- bomber ---
	step EQU (29 *4)
	dist EQU hit+(5*step)
	adist EQU hit+(((1838 %4000) *2)*step)+2

stloc equ (boot+2000)
cloc equ (stloc-3+(2*step)+2)
Mgap equ (cloc-stloc)
istep equ 2731

sto:	spl #-(2*step),>-(2*step)
ref:	mov <adist,}dist
hit:	mov bmb,@ref
chk:	sub.f sto,ref
	djn.f ref,{-3029
for 11
	dat 0,0
rof
bmb:	mov step,1
for 20
	dat 0,0
rof

boot:	mov #-Mgap+35,cloc-13
	mov sbm,cloc-8
	mov {-1,<-1
	mov bmb,stloc+11
	spl 2,<sto-4
	spl 2,<sto-5
	spl 1,<sto-6
	mov <3,{2
	mov {clr,{2
sgo:	djn stloc,#5
cgo:	djn.f cloc+1,#sto+5

gate:	dat 0,0
for 3
	dat 0,0
rof
sw:	dat <1,(clr+5-gate)
sbm:	spl #clr+4620,(clr+7-gate)
for 3
	dat 0,0
rof
clr:	spl #5,>gate-(2*istep)
clop:	mov *sw,>gate
	mov *sw,>gate
	djn.f clop,}sbm

end boot