;redcode-cwset2005
;name toffee apple
;author John Metcalf
;strategy miniQ^3 -> airbag stun bomber / 5-point imps
;assert CORESIZE==8192

     org   qGo

     sStep equ 824
     iStep equ 3277
     iBoot equ boot+200

boot:mov.i {-999,    #0
loop:mov   sBmb,     <ptr
     mov   fBmb,     *ptr
ptr: mov   3*sStep+2,*5*sStep+2
     add   inc,      ptr
gate:mov   >jBmb,    @ptr
     jmz   loop,     <jBmb

inc: spl   #3*sStep, <3*sStep+1
clr: mov   dBmb,     >gate
     djn.f clr,      >gate
dBmb:dat   1,        7

     for   4
     dat   0,0
     rof

fBmb:jmp   @sStep,   sStep-1
sBmb:spl   #1-sStep, 1
jBmb:jmp   -1,       0

     for   21
     dat   0,        0
     rof

pGo: mov   imp,      iBoot
     spl   iGo,      <333
     spl   1,        <444
     spl   1,        <555
     mov.i {0,       #0
     jmp   >boot,    <777
iGo: spl   1,        <888
     spl   1,        <999
     spl   1,        <1111
     jmp   @vect,    }0

vect:jmp   #1,       iBoot+iStep*0
     jmp   #1,       iBoot+iStep*1
     jmp   #1,       iBoot+iStep*2
     jmp   #1,       iBoot+iStep*3
     jmp   #1,       iBoot+iStep*4
     jmp   #1,       iBoot+iStep*5
     jmp   #1,       iBoot+iStep*6
     jmp   #1,       iBoot+iStep*7

imp: mov.i #iStep,   *0

     qf equ qKil
     qs equ 250
     qd equ 360
     qi equ 7
     qr equ 11

qGo: seq   qd+qf+qs,    qf+qs      ; 1
     djn.f qSki,        {qd+qf+qs+qi
     seq   qd+qf+6*qs,  qf+6*qs    ; B
     djn.f qFas,        {qd+qf+6*qs+qi
     seq   qd+qf+5*qs,  qf+5*qs    ; B-1
     jmp   qFas,        <qBmb
     seq   qd+qf+7*qs,  qf+7*qs    ; B+1
     jmp   qFas,        >qBmb
     seq   qd+qf+9*qs,  qf+9*qs    ; A-1
     djn   qFas,        {qFas
     seq   qd+qf+10*qs, qf+10*qs   ; A
     jmn   qFas,        {qFas

     seq   qd+qf+3*qs,  qf+3*qs    ; C
     djn.f >qFas,       {qd+qf+3*qs+qi
     seq   qd+qf+2*qs,  qf+2*qs    ; C-1
     jmn   >qFas,       {qSlo
     seq   qd+qf+4*qs,  qf+4*qs    ; C+1
     jmn   >qFas,       }qSlo
     seq   qd+qf+12*qs, qf+12*qs   ; B*C-B
     jmn   qSlo,        {qSlo
     seq   qd+qf+15*qs, qf+15*qs   ; B*C-C
     jmp   qSlo,        <qBmb
     seq   qd+qf+21*qs, qf+21*qs   ; B*C+C
     jmp   qSlo,        >qBmb
     seq   qd+qf+24*qs, qf+24*qs   ; B*C+B
     jmn   qSlo,        }qSlo
     seq   qd+qf+27*qs, qf+27*qs   ; A*C-C
     djn   qSlo,        {qFas
     seq   qd+qf+30*qs, qf+30*qs   ; A*C
     jmn   qSlo,        {qFas
     sne   qd+qf+18*qs, qf+18*qs   ; B*C
     jmz.f pGo,         qd+qf+18*qs-10

qSlo:mul   #3,          qKil       ; C=3
qFas:mul.b qBmb,        @qSlo
qSki:sne   >qf+23*qs,   >qKil
     add   #qd,         qKil
qLoo:mov   *qKil,       <qKil
qKil:mov   qBmb,        }qs
     sub   #qi-1,       @qLoo
     djn   qLoo,        #qr
     djn.f pGo,         <10        ; A=10
qBmb:dat   {qi*qr-10,   {6         ; B=6
     end