;redcode-94
;name Wash'n'Go
;author inversed
;strategy qScan -> Clear/Imp for CSEC2005 round 2
;assert CORESIZE==8192
;Few modern warriors would score good with such rules
;but many older ones feel just fine: Iron Gate, Blue Funk,
;B-Panama X worked with only a few changes. I've tried 
;different strategies, but this worked best amongst my warriors.
;It only looses to papers and spl/jmp scanners with good gates 
;(Romulan Warbird for example). Let's hope that datagram's
;entry isn't one of those. And it has some problems if
;maxprocesses is 24. It'd be ridiculous if it is.

bptr	equ	(s-3)
bd1	equ	2000	;2310
istep	equ	2731
io	equ	id+(istep/2)
id	equ	1331	;4567
h	equ	1337	;leet step ;)

f	equ	5151
y	equ	6111

dq	equ	(y+1)%CORESIZE
qa1	equ	(1+f*(qt1-1-found))%CORESIZE
qa2	equ	(1+f*(qt1  -found))%CORESIZE
qb1	equ	(1+f*(qt2-1-found))%CORESIZE
qb2	equ	(1+f*(qt2  -found))%CORESIZE
qb3	equ	(1+f*(qt2+1-found))%CORESIZE
qc2	equ	(1+f*(qt3  -found))%CORESIZE

qt3	equ	qbomb

org	qgo

	dat	0,	qb1
qt2	dat	0,	qb2
	dat	0,	qb3

wgo	mov	imp,	imp+io
	spl	1,	0
	mov	<bp1,	{bp1
	spl	1,	0
	mov	<bp1,	{bp1
	mov	<bpi,	{bpi

bpi	spl	imp+id,	imp
bp1	jmp	bomb+1+bd1,	bomb+1

s	spl	#0,	>bptr
	spl	#0,	>bptr
	mov	bomb,	>bptr
	djn.f	-1,	>bptr
	dat	0,	0	;jmp	-2,	>bptr
bomb	dat	0,	11

inc	spl	#istep,	h
	add	inc,	ptr
ptr	djn.f	imp-istep-1+(io-id),	{0
	dat	0,	0
imp	mov.i	#istep,	*0

	dat	0,	qa1
qt1	dat	0,	qa2

for	40
	dat	0,	0
	rof

	;q0 mutations 
qgo	sne	found+dq*qc2,	found+dq*qc2+qb2
	seq	<qt3,		found+dq*(qc2-1)+qb2
	jmp	q0,		}q0

	sne	found+dq*qa1,	found+dq*qa1+qb2
	seq	<qt1-1,		found+dq*(qa1-1)+qb2
        djn.a	q0,		{q0

	sne	found+dq*qa2,	found+dq*qa2+qb2
	seq	<qt1,		found+dq*(qa2-1)+qb2
	jmp	q0,		{q0

	;q1 mutations 
	sne	found+dq*qb1,	found+dq*qb1+qb1
	seq	<qt2-1,		found+dq*(qb1-1)+(qb1-1)
	jmp	q0,		{q1

	sne	found+dq*qb3,	found+dq*qb3+qb3
	seq	<qt2+1,		found+dq*(qb3-1)+(qb3-1)
	jmp	q0,		}q1

	;no mutation 
	sne	found+dq*qb2,	found+dq*qb2+qb2
        seq	<qt2,		found+dq*(qb2-1)+(qb2-1)
	jmp	q0,		0


	;dq mutation 
	seq	>found,		found+dq+(qb2-1)
	jmp	qsel,		<found

	;q0 mutation
	seq	found+(dq+1)*(qc2-1),	found+(dq+1)*(qc2-1)+(qb2-1)
	jmp	q0,			}q0

	seq	found+(dq+1)*(qa2-1),	found+(dq+1)*(qa2-1)+(qb2-1)
	jmp	q0,			{q0

	seq	found+(dq+1)*(qa1-1),	found+(dq+1)*(qa1-1)+(qb2-1)
	djn.a	q0,			{q0 

        ;free scan
	jmz.f	wgo,			found+(dq+1)*(qb2-1)+(qb2-1)
	
q0	mul.b	*q1,	 found
qsel	sne	<qt1,	@found
q1	add.b	qt2,	 found

qoff	equ	-86
qtime	equ	20
qstep	equ	7

qloop	mov	qbomb,	@found
found	mov	qbomb,	}dq
	add	#qstep,	found
	djn	qloop,	#qtime
	jmp	wgo,	0
qbomb	dat	{qoff,	qc2